test_27.f90

Go to the documentation of this file.

MODULE test_27
  IMPLICIT NONE
  !TEST 27
  !DCQ Test  mu_var_theta_vaccuum
  REAL (kind=8),PARAMETER,PUBLIC :: ratio_mu_T27 = 50.0d0 ! the variation of mu
  REAL (kind=8),PUBLIC :: b_factor_T27 = (2**6) * (ratio_mu_T27-1.d0)/(ratio_mu_T27+1.d0)
  INTEGER,      PUBLIC :: mode_mu_T27 = 4
  REAL (kind=8),PUBLIC :: omega_T27 = 1.d0
CONTAINS

  !===Analytical mu_in_fourier_space (if needed)
  FUNCTION mu_bar_in_fourier_space_anal_t27(H_mesh,nb,ne,pts,pts_ids) RESULT(vv)
    USE def_type_mesh
    USE input_data
    USE my_util
    IMPLICIT NONE
    TYPE(mesh_type)                            :: h_mesh
    REAL(KIND=8), DIMENSION(ne-nb+1)           :: vv
    INTEGER                                    :: nb, ne
    REAL(KIND=8),DIMENSION(2,ne-nb+1),OPTIONAL :: pts
    INTEGER,DIMENSION(ne-nb+1),OPTIONAL        :: pts_ids
    REAL(KIND=8),DIMENSION(ne-nb+1)            :: r,z

    IF( present(pts) .AND. present(pts_ids) ) THEN !Computing mu at  pts
       r=pts(1,nb:ne)
       z=pts(2,nb:ne)
    ELSE
       r=h_mesh%rr(1,nb:ne) !Computing mu  at nodes
       z=h_mesh%rr(2,nb:ne)
    END IF

    vv=1.d0/(1.d0+abs(f_test_t27(r,z)))
    RETURN
  END FUNCTION mu_bar_in_fourier_space_anal_t27

  !===Analytical mu_in_fourier_space (if needed)
  FUNCTION grad_mu_bar_in_fourier_space_anal_t27(pt,pt_id) RESULT(vv)
    USE input_data
    USE my_util
    IMPLICIT NONE
    REAL(KIND=8),DIMENSION(2)           :: pt,vv
    INTEGER,DIMENSION(1)                :: pt_id
    REAL(KIND=8),DIMENSION(1)           :: tmp,r,z
    REAL(KIND=8)                        :: sign
    INTEGER      :: n

    r(1)=pt(1)
    z(1)=pt(2)
    tmp=f_test_t27(r,z)

    IF (tmp(1) .GE. 0.d0 ) THEN
       sign =1.0
    ELSE
       sign =-1.0
    END IF

    vv(1)=-sign*dfdr_test_t27(r(1),z(1))/(1.d0 +abs(tmp(1)))**2
    vv(2)=-sign*dfdz_test_t27(r(1),z(1))/(1.d0 +abs(tmp(1)))**2
    RETURN

    !===Dummies variables to avoid warning
    n=pt_id(1)
    !===Dummies variables to avoid warning
  END FUNCTION grad_mu_bar_in_fourier_space_anal_t27

  FUNCTION mu_in_real_space_anal_t27(H_mesh,angles,nb_angles,nb,ne,time) RESULT(vv)
    USE def_type_mesh
    IMPLICIT NONE
    TYPE(mesh_type)                            :: h_mesh
    REAL(KIND=8), DIMENSION(:)                 :: angles
    INTEGER                                    :: nb_angles
    INTEGER                                    :: nb, ne
    REAL(KIND=8)                               :: time
    REAL(KIND=8), DIMENSION(nb_angles,ne-nb+1) :: vv
    INTEGER                                    :: ang

    DO ang = 1, nb_angles
       vv(ang,:) = 1/(1+f_test_wtime_t27(h_mesh%rr(1,nb:ne),h_mesh%rr(2,nb:ne),time)*cos(mode_mu_t27*angles(ang)))
    END DO
  END FUNCTION mu_in_real_space_anal_t27

  FUNCTION f_test_t27(r,z) RESULT(vv)
    IMPLICIT NONE
    REAL(KIND=8), DIMENSION(:), INTENT(IN) :: r, z
    REAL(KIND=8), DIMENSION(SIZE(r))       :: vv

    vv = b_factor_t27*(r*(1-r)*(z**2-1))**3
    RETURN
  END FUNCTION f_test_t27

  FUNCTION f_test_wtime_t27(r,z,t) RESULT(vv)
    IMPLICIT NONE
    REAL(KIND=8), DIMENSION(:), INTENT(IN) :: r, z
    REAL(KIND=8), INTENT(IN)               :: t
    REAL(KIND=8), DIMENSION(SIZE(r))       :: vv

    vv = b_factor_t27*cos(omega_t27*t)*(r*(1-r)*(z**2-1))**3
    RETURN
  END FUNCTION f_test_wtime_t27

  FUNCTION dfdr_test_t27(r,z) RESULT(vv)
    IMPLICIT NONE
    REAL(KIND=8), INTENT(IN):: r, z
    REAL(KIND=8)            :: vv
    vv = 3 * b_factor_t27 * (z**2-1)**3 * (r*(1-r))**2 * (1-2*r)
    RETURN
  END FUNCTION dfdr_test_t27

  FUNCTION dfdr_test_wtime_t27(r,z, t) RESULT(vv)
    IMPLICIT NONE
    REAL(KIND=8), INTENT(IN):: r, z,t
    REAL(KIND=8)            :: vv
    vv = 3 * b_factor_t27 * cos(omega_t27*t) * (z**2-1)**3 * (r*(1-r))**2 * (1-2*r)
    RETURN
  END FUNCTION dfdr_test_wtime_t27

  FUNCTION dfdz_test_t27(r,z) RESULT(vv)
    IMPLICIT NONE
    REAL(KIND=8), INTENT(IN):: r, z
    REAL(KIND=8)            :: vv
    vv = 3*b_factor_t27*(r*(1-r))**3*(z**2-1)**2*(2*z)
    RETURN
  END FUNCTION dfdz_test_t27

  FUNCTION dfdz_test_wtime_t27(r,z,t) RESULT(vv)
    IMPLICIT NONE
    REAL(KIND=8), INTENT(IN):: r, z,t
    REAL(KIND=8)            :: vv
    vv = 3*b_factor_t27*cos(omega_t27*t) *(r*(1-r))**3*(z**2-1)**2*(2*z)
    RETURN
  END FUNCTION dfdz_test_wtime_t27

END MODULE test_27